Query Syntax

expression      : term
                | expression or term
                ;
or              : %prec `or' 
                | `or' 
                ;
and             : `and' 
                | `not' 
                ;
term            : factor
                | term and factor
                ;
factor          : unit
                | unit `pre/' unit
                | unit `w/' unit
                | `atleast/' unit
                ;
unit            : word-or-literal 
                | phonsound word-or-literal
                | `(' expression `)'
                | word-or-literal  `=' `(' s_expression `)'
                | word-or-literal  `='  word-or-literal
                | word-or-literal  `='  phonsound word-or-literal
                | word-or-literal relop word-or-literal
                ;
relop           : `=' `=' 
                | `<'     
                | `>'     
                ;
phonsound       : PHONIX
                | SOUNDEX
                ;
s_expression    : s_term 
                | s_expression or s_term
                ;
s_term          : s_factor 
                | s_term and s_factor 
                ;
s_factor        : s_unit
                | s_unit `pre/' s_unit
                | s_unit `w/' s_unit
                | `atleast/' s_unit
                ;
s_unit          : word-or-literal
                | phonsound word-or-literal
                | `(' s_expression `)'
                ;